PROGRAM RAY DEM
C This program demonstrates the use of the coefficients calculated
C  by the programs trntrx. The program will produce a table of values
C  for different values of lambda as set in the DATA statements.
C
      DOUBLE PRECISION DLAMDA(7),RAY,RAY11,RAY12,RAY21,RAY22
      INTEGER J
      DATA DLAMDA/1D0,.5D0,.25D0,.2D0,.125D0,.1D0,2D0/
      WRITE(6,5)
 5    FORMAT(1X,
     &'RESISTANCE FUNCTIONS RAY from Jeffrey & Onishi,1982, J.F.M.,')
      WRITE(6,7)
 7    FORMAT(1X,'VOL. 139, p261')
      WRITE(6,8)
 8    FORMAT(1X,
     &'Table for the Functions RAY for 0.1<lambda<1.')
      WRITE(6,10)
10    FORMAT(/1X,
     & ' LAMBDA     RAY11      RAY12     RAY21     RAY22'/)
      DO 50 J=1,7
        RAY11=RAY(1,1,DLAMDA(J))
        RAY12=RAY(1,2,DLAMDA(J))
        RAY21=RAY(2,1,DLAMDA(J))
        RAY22=RAY(2,2,DLAMDA(J))
   50 WRITE(6,101)DLAMDA(J),RAY11,RAY12,RAY21,RAY22
  101 FORMAT(1X,F7.3,4F11.5)
      STOP
      END
C
      DOUBLE PRECISION FUNCTION RAY(IALPHA,IBETA,DLAMDA)
C ----------------------- Arguments of function -----------------------
      INTEGER IALPHA,IBETA
      DOUBLE PRECISION DLAMDA
C ---------------------------------------------------------------------
C                                           Y
C This subprogram calculates the functions A  defined in
C  Jeffrey & Onishi (1984) J. Fluid Mech vol 139, 261-290.
C  Equations 4.17 and 4.18 are evaluated using coefficients read from unit 2,
C  and conforming to those generated by one of the programs trntrx.
C  The subprogram works by converting any call to one in which lambda.LT.1
C  It goes forwards or backwards through the coefficients (the variable ISTEP)
C  depending upon whether I=1 or 2.
C
C --------------------------- Local variables -------------------------
      DOUBLE PRECISION RYACOF(0:45450),XL,XLP1,G2,G3,G2SUM,G3SUM
      DOUBLE PRECISION ZT,ZL,COEF
      INTEGER I,J,ISTEP,IQ,MMIN,MMAX,M,NM, MAXS
      LOGICAL LOADED
      CHARACTER*4 ID
      DATA LOADED/.FALSE./
C ------------------------ Start of executable code -------------------
      IF(.NOT.LOADED) THEN
        OPEN(1,FILE='rya300.dat',STATUS='OLD')
        READ(1,10)  ID,MAXS
10      FORMAT(A4,I5)
        IF(ID.NE.' RYA') THEN
          WRITE(*,20)
20        FORMAT(1X,'WRONG COEFFICIENTS FOR RYA')
          STOP
        ENDIF
        READ(1,30) RYACOF
30      FORMAT(D22.16)
        CLOSE(1)
        LOADED=.TRUE.
      ENDIF
      IF(DLAMDA.GT.1D0) THEN
        I=3-IALPHA
        J=3-IBETA
        XL=1D0/DLAMDA
      ELSE
        I=IALPHA
        J=IBETA
        XL=DLAMDA
      ENDIF
      XLP1=XL+1D0
C
C  These Gx are the functions g<x> from Jeffrey & Onishi.
      IF(I.EQ.1) THEN
        G2=4D0*(2D0*XL+XL**2+2D0*XL**3)/(15D0*XLP1**3)
        G3=2D0*(16D0-45D0*XL+58D0*XL**2-45D0*XL**3+16D0*XL**4)
     &        /(375D0*XLP1**3)
        ISTEP=1
      ELSE
        G2=4D0*(2D0+XL+2D0*XL**2)/(15D0*XLP1**3)
        G3=2D0*(16D0-45D0*XL+58D0*XL**2-45D0*XL**3+16D0*XL**4)
     &        /(375D0*XL*XLP1**3)
        ISTEP=-1
      ENDIF
      IF(I.EQ.J) THEN
        RAY=1D0-G3
        MMIN=2
        MMAX=MAXS
      ELSE
        RAY=2D0*(G2*DLOG(2D0)-G3)
        MMIN=1
        MMAX=MAXS-1
      ENDIF
      G2SUM=2D0*G2
      G3SUM=4D0*G3
      DO 100 M=MMIN,MMAX,2
        IF (ISTEP.GT.0) THEN
          NM = (M*(M+1))/2
        ELSE
          NM = (M*(M+1))/2 +M
        ENDIF
        ZL=XLP1**(-M)
        COEF=0D0
        DO 50 IQ=0,M
          COEF=COEF+RYACOF(NM)*ZL
          NM=NM+ISTEP
          ZL=ZL*XL
   50   CONTINUE
        RAY=RAY+COEF-(G2SUM-G3SUM/DBLE(M+2))/DBLE(M)
  100 CONTINUE
      IF(I.EQ.J)RETURN
      RAY=-RAY*2D0/XLP1
      IF(I.EQ.2)RAY=RAY*XL
      RETURN
      END